home *** CD-ROM | disk | FTP | other *** search
/ PCGUIA 127 / PC Guia 127.iso / Software / Produtividade / OpenOffice.org 2.0.1 / openofficeorg2.cab / ooo2wordml_table.xsl < prev    next >
Extensible Markup Language  |  2005-09-10  |  26KB  |  425 lines
  1. <?xml version="1.0" encoding="UTF-8"?>
  2. <!--
  3.  
  4.     OpenOffice.org - a multi-platform office productivity suite
  5.  
  6.     $RCSfile: ooo2wordml_table.xsl,v $
  7.  
  8.     $Revision: 1.8 $
  9.  
  10.     last change: $Author: rt $ $Date: 2005/09/08 22:07:44 $
  11.  
  12.     The Contents of this file are made available subject to
  13.     the terms of GNU Lesser General Public License Version 2.1.
  14.  
  15.  
  16.       GNU Lesser General Public License Version 2.1
  17.       =============================================
  18.       Copyright 2005 by Sun Microsystems, Inc.
  19.       901 San Antonio Road, Palo Alto, CA 94303, USA
  20.  
  21.       This library is free software; you can redistribute it and/or
  22.       modify it under the terms of the GNU Lesser General Public
  23.       License version 2.1, as published by the Free Software Foundation.
  24.  
  25.       This library is distributed in the hope that it will be useful,
  26.       but WITHOUT ANY WARRANTY; without even the implied warranty of
  27.       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  28.       Lesser General Public License for more details.
  29.  
  30.       You should have received a copy of the GNU Lesser General Public
  31.       License along with this library; if not, write to the Free Software
  32.       Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  33.       MA  02111-1307  USA
  34.  
  35. -->
  36. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:w="http://schemas.microsoft.com/office/word/2003/wordml" xmlns:wx="http://schemas.microsoft.com/office/word/2003/auxHint" xmlns:o="urn:schemas-microsoft-com:office:office" xmlns:aml="http://schemas.microsoft.com/aml/2001/core" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:v="urn:schemas-microsoft-com:vml" xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" xmlns:w10="urn:schemas-microsoft-com:office:word" xmlns:draw="urn:oasis:names:tc:opendocument:xmlns:drawing:1.0" xmlns:dc="http://purl.org/dc/elements/1.1/" xmlns:meta="urn:oasis:names:tc:opendocument:xmlns:meta:1.0" xmlns:number="urn:oasis:names:tc:opendocument:xmlns:datastyle:1.0" xmlns:svg="urn:oasis:names:tc:opendocument:xmlns:svg-compatible:1.0" xmlns:chart="urn:oasis:names:tc:opendocument:xmlns:chart:1.0" xmlns:dr3d="urn:oasis:names:tc:opendocument:xmlns:dr3d:1.0" xmlns:math="http://www.w3.org/1998/Math/MathML" xmlns:form="urn:oasis:names:tc:opendocument:xmlns:form:1.0" xmlns:script="urn:oasis:names:tc:opendocument:xmlns:script:1.0" xmlns:config="urn:oasis:names:tc:opendocument:xmlns:config:1.0" xmlns:ooo="http://openoffice.org/2004/office" xmlns:ooow="http://openoffice.org/2004/writer" xmlns:oooc="http://openoffice.org/2004/calc" xmlns:dom="http://www.w3.org/2001/xml-events" exclude-result-prefixes="office table style text draw svg   dc config xlink meta oooc dom ooo chart math dr3d form script ooow draw">
  37.     <xsl:key name="table-style" match="style:style[@style:family='table']" use="@style:name"/>
  38.     <xsl:key name="table-column-style" match="style:style[@style:family='table-column']" use="@style:name"/>
  39.     <xsl:key name="table-row-style" match="style:style[@style:family='table-row']" use="@style:name"/>
  40.     <xsl:key name="table-cell-style" match="style:style[@style:family='table-cell']" use="@style:name"/>
  41.     <xsl:template match="style:table-properties" mode="table">
  42.         <xsl:param name="within-body"/>
  43.         <xsl:if test="$within-body = 'yes'">
  44.             <w:tblW>
  45.                 <xsl:choose>
  46.                     <xsl:when test="@style:rel-width">
  47.                         <xsl:attribute name="w:w"><xsl:value-of select="substring-before(@style:rel-width, '%') * 50"/></xsl:attribute>
  48.                         <xsl:attribute name="w:type">pct</xsl:attribute>
  49.                     </xsl:when>
  50.                     <xsl:when test="@style:width">
  51.                         <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="@style:width"/></xsl:call-template></xsl:attribute>
  52.                         <xsl:attribute name="w:type">dxa</xsl:attribute>
  53.                     </xsl:when>
  54.                     <xsl:otherwise>
  55.                         <xsl:attribute name="w:w">0</xsl:attribute>
  56.                         <xsl:attribute name="w:type">auto</xsl:attribute>
  57.                     </xsl:otherwise>
  58.                 </xsl:choose>
  59.             </w:tblW>
  60.         </xsl:if>
  61.         <w:tblInd>
  62.             <xsl:choose>
  63.                 <xsl:when test="@fo:margin-left">
  64.                     <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="@fo:margin-left"/></xsl:call-template></xsl:attribute>
  65.                     <xsl:attribute name="w:type">dxa</xsl:attribute>
  66.                 </xsl:when>
  67.                 <xsl:otherwise>
  68.                     <xsl:attribute name="w:w">0</xsl:attribute>
  69.                     <xsl:attribute name="w:type">auto</xsl:attribute>
  70.                 </xsl:otherwise>
  71.             </xsl:choose>
  72.         </w:tblInd>
  73.         <xsl:if test="@table:align">
  74.             <w:jc>
  75.                 <xsl:choose>
  76.                     <xsl:when test="@table:align = 'left' or @table:align= 'center' or @table:align = 'right'">
  77.                         <xsl:attribute name="w:val"><xsl:value-of select="@table:align"/></xsl:attribute>
  78.                     </xsl:when>
  79.                     <xsl:otherwise>
  80.                         <xsl:attribute name="w:val">left</xsl:attribute>
  81.                     </xsl:otherwise>
  82.                 </xsl:choose>
  83.             </w:jc>
  84.         </xsl:if>
  85.     </xsl:template>
  86.     <xsl:template match="table:table">
  87.         <!--fix for issue i32030 pagebreak before-->
  88.         <xsl:if test="key('table-style', @table:style-name)/style:table-properties/@fo:break-before">
  89.             <xsl:variable name="table-break-before" select="key('table-style', @table:style-name)/style:table-properties/@fo:break-before"/>
  90.             <xsl:choose>
  91.                 <xsl:when test="$table-break-before = 'page' ">
  92.                     <w:p>
  93.                         <w:r>
  94.                             <w:br w:type="page"/>
  95.                         </w:r>
  96.                     </w:p>
  97.                 </xsl:when>
  98.                 <xsl:when test="$table-break-before = 'column' ">
  99.                     <w:p>
  100.                         <w:r>
  101.                             <w:br w:type="column"/>
  102.                         </w:r>
  103.                     </w:p>
  104.                 </xsl:when>
  105.             </xsl:choose>
  106.         </xsl:if>
  107.         <w:tbl>
  108.             <w:tblPr>
  109.                 <xsl:if test="not (@table:is-sub-table) or (@table:is-sub-table = 'false' )">
  110.                     <w:tblStyle w:val="{@table:style-name}"/>
  111.                     <xsl:apply-templates select="key('table-style', @table:style-name)/style:table-properties" mode="table">
  112.                         <xsl:with-param name="within-body" select="'yes'"/>
  113.                     </xsl:apply-templates>
  114.                 </xsl:if>
  115.                 <xsl:if test="@table:is-sub-table ='true' ">
  116.                     <w:tblW w:type="dxa">
  117.                         <xsl:variable name="sub-table-width">
  118.                             <xsl:call-template name="caculate-sub-table-width">
  119.                                 <xsl:with-param name="sub-table-column-node" select="table:table-column[1]"/>
  120.                                 <xsl:with-param name="total-sub-table-width" select="0"/>
  121.                             </xsl:call-template>
  122.                         </xsl:variable>
  123.                         <xsl:attribute name="w:w"><xsl:value-of select="$sub-table-width"/></xsl:attribute>
  124.                     </w:tblW>
  125.                     <!--w:tblLayout w:type="Fixed"/-->
  126.                 </xsl:if>
  127.             </w:tblPr>
  128.             <w:tblGrid>
  129.                 <xsl:apply-templates select="table:table-column"/>
  130.             </w:tblGrid>
  131.             <xsl:apply-templates select="table:table-header-rows/table:table-row | table:table-row"/>
  132.         </w:tbl>
  133.         <!--fix for issue i32030 pagebreak after-->
  134.         <xsl:if test="key('table-style', @table:style-name)/style:table-properties/@fo:break-after">
  135.             <xsl:variable name="table-break-after" select="   key('table-style', @table:style-name)/style:table-properties/@fo:break-after"/>
  136.             <xsl:choose>
  137.                 <xsl:when test="$table-break-after = 'page' ">
  138.                     <w:p>
  139.                         <w:r>
  140.                             <w:br w:type="page"/>
  141.                         </w:r>
  142.                     </w:p>
  143.                 </xsl:when>
  144.                 <xsl:when test="$table-break-after = 'column' ">
  145.                     <w:p>
  146.                         <w:r>
  147.                             <w:br w:type="column"/>
  148.                         </w:r>
  149.                     </w:p>
  150.                 </xsl:when>
  151.             </xsl:choose>
  152.         </xsl:if>
  153.         <xsl:if test="name(..)= 'table:table-cell' ">
  154.             <w:p/>
  155.         </xsl:if>
  156.     </xsl:template>
  157.     <xsl:template name="caculate-sub-table-width">
  158.         <xsl:param name="sub-table-column-node"/>
  159.         <xsl:param name="total-sub-table-width"/>
  160.         <xsl:variable name="column-width" select="key('table-column-style', $sub-table-column-node/@table:style-name)/style:table-column-properties/@style:column-width"/>
  161.         <xsl:variable name="column-width-in-twip">
  162.             <xsl:call-template name="convert2twip">
  163.                 <xsl:with-param name="value" select="$column-width"/>
  164.             </xsl:call-template>
  165.         </xsl:variable>
  166.         <xsl:choose>
  167.             <xsl:when test="$sub-table-column-node/following-sibling::table:table-column">
  168.                 <xsl:choose>
  169.                     <xsl:when test="$sub-table-column-node/@table:number-columns-repeated">
  170.                         <xsl:call-template name="caculate-sub-table-width">
  171.                             <xsl:with-param name="sub-table-column-node" select="$sub-table-column-node/following-sibling::table:table-column[ 1]"/>
  172.                             <xsl:with-param name="total-sub-table-width" select="$total-sub-table-width + $column-width-in-twip *  $sub-table-column-node/@table:number-columns-repeated"/>
  173.                         </xsl:call-template>
  174.                     </xsl:when>
  175.                     <xsl:otherwise>
  176.                         <xsl:call-template name="caculate-sub-table-width">
  177.                             <xsl:with-param name="sub-table-column-node" select="$sub-table-column-node/following-sibling::table:table-column[1]"/>
  178.                             <xsl:with-param name="total-sub-table-width" select="$total-sub-table-width + $column-width-in-twip "/>
  179.                         </xsl:call-template>
  180.                     </xsl:otherwise>
  181.                 </xsl:choose>
  182.             </xsl:when>
  183.             <xsl:otherwise>
  184.                 <xsl:choose>
  185.                     <xsl:when test="$sub-table-column-node/@table:number-columns-repeated">
  186.                         <xsl:value-of select="$total-sub-table-width + $column-width-in-twip *  $sub-table-column-node/@table:number-columns-repeated"/>
  187.                     </xsl:when>
  188.                     <xsl:otherwise>
  189.                         <xsl:value-of select="$total-sub-table-width + $column-width-in-twip "/>
  190.                     </xsl:otherwise>
  191.                 </xsl:choose>
  192.             </xsl:otherwise>
  193.         </xsl:choose>
  194.     </xsl:template>
  195.     <xsl:template match="table:table-column">
  196.         <xsl:variable name="column-width" select="key('table-column-style', @table:style-name)/style:table-column-properties/@style:column-width"/>
  197.         <xsl:variable name="column-width-in-twip">
  198.             <xsl:call-template name="convert2twip">
  199.                 <xsl:with-param name="value" select="$column-width"/>
  200.             </xsl:call-template>
  201.         </xsl:variable>
  202.         <xsl:choose>
  203.             <!-- if table:table-column has attribute table:number-columns-repeated, then call the recursion
  204.             temple repeat-gridcol to produce multiple w:gridCol in MS word. Gary.Yang   -->
  205.             <xsl:when test="@table:number-columns-repeated">
  206.                 <xsl:call-template name="repeat-gridcol">
  207.                     <xsl:with-param name="grid-repeat-count" select="@table:number-columns-repeated"/>
  208.                     <xsl:with-param name="column-width" select="$column-width-in-twip"/>
  209.                 </xsl:call-template>
  210.             </xsl:when>
  211.             <xsl:otherwise>
  212.                 <w:gridCol w:w="{$column-width-in-twip}"/>
  213.             </xsl:otherwise>
  214.         </xsl:choose>
  215.     </xsl:template>
  216.     <!--recursion template for produce multiple w:gridCol  Gary.Yang-->
  217.     <xsl:template name="repeat-gridcol">
  218.         <xsl:param name="grid-repeat-count"/>
  219.         <xsl:param name="column-width"/>
  220.         <xsl:if test="$grid-repeat-count > 0">
  221.             <w:gridCol w:w="{$column-width}"/>
  222.             <xsl:call-template name="repeat-gridcol">
  223.                 <xsl:with-param name="grid-repeat-count" select="$grid-repeat-count - 1"/>
  224.                 <xsl:with-param name="column-width" select="$column-width"/>
  225.             </xsl:call-template>
  226.         </xsl:if>
  227.     </xsl:template>
  228.     <xsl:template match="table:table-row">
  229.         <xsl:element name="w:tr">
  230.             <xsl:element name="w:trPr">
  231.                 <xsl:if test="parent::table:table-header-rows">
  232.                     <!-- fix for  Issue 32034-->
  233.                     <w:tblHeader>on</w:tblHeader>
  234.                 </xsl:if>
  235.                 <xsl:variable name="row-height" select="key('table-row-style', @table:style-name)/style:table-row-properties/@style:row-height"/>
  236.                 <xsl:if test="$row-height">
  237.                     <w:trHeight>
  238.                         <xsl:attribute name="w:val"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="$row-height"/></xsl:call-template></xsl:attribute>
  239.                     </w:trHeight>
  240.                 </xsl:if>
  241.             </xsl:element>
  242.             <!--end of w:trPr-->
  243.             <xsl:apply-templates select="table:table-cell "/>
  244.         </xsl:element>
  245.     </xsl:template>
  246.     <xsl:template match="table:table-cell ">
  247.         <xsl:element name="w:tc">
  248.             <xsl:element name="w:tcPr">
  249.                 <!-- to caclate the table-cell width Gary.Yang -->
  250.                 <xsl:choose>
  251.                     <!--when the table-cell  contains the sub-table -->
  252.                     <xsl:when test="table:table/@table:is-sub-table= 'true' ">
  253.                         <xsl:variable name="table-cell-width">
  254.                             <xsl:call-template name="caculate-sub-table-width">
  255.                                 <xsl:with-param name="sub-table-column-node" select="table:table/table:table-column[1]"/>
  256.                                 <xsl:with-param name="total-sub-table-width" select="0"/>
  257.                             </xsl:call-template>
  258.                         </xsl:variable>
  259.                         <w:tcW w:type="dxa">
  260.                             <xsl:attribute name="w:w"><xsl:value-of select="$table-cell-width"/></xsl:attribute>
  261.                         </w:tcW>
  262.                     </xsl:when>
  263.                     <xsl:otherwise>
  264.                         <!-- when the table-cell doesn't contain the sub-table -->
  265.                         <xsl:variable name="table-cell-width">
  266.                             <xsl:call-template name="caculate-table-cell-width">
  267.                                 <xsl:with-param name="table-cell-position" select="position()"/>
  268.                                 <xsl:with-param name="table-column" select="ancestor::table:table[1]/table:table-column[1]"/>
  269.                             </xsl:call-template>
  270.                         </xsl:variable>
  271.                         <w:tcW w:type="dxa">
  272.                             <xsl:attribute name="w:w"><xsl:value-of select="$table-cell-width"/></xsl:attribute>
  273.                         </w:tcW>
  274.                         <!-- for performance issue, we can set w:type to auto that makes the cell width auto fit the content. -->
  275.                         <!--w:tcW w:w="0" w:type="auto"/-->
  276.                     </xsl:otherwise>
  277.                 </xsl:choose>
  278.                 <xsl:if test="@table:number-columns-spanned">
  279.                     <w:gridSpan w:val="{@table:number-columns-spanned}"/>
  280.                 </xsl:if>
  281.                 <xsl:variable name="cell-style-properties" select="key('table-cell-style', @table:style-name)/style:table-cell-properties"/>
  282.                 <xsl:if test="$cell-style-properties/@fo:background-color">
  283.                     <w:shd w:val="solid" w:color="{substring-after($cell-style-properties/@fo:background-color,'#')}"/>
  284.                 </xsl:if>
  285.                 <xsl:if test="$cell-style-properties/@fo:vertical-align">
  286.                     <xsl:choose>
  287.                         <xsl:when test="$cell-style-properties/@fo:vertical-align = 'middle'">
  288.                             <w:vAlign w:val="center"/>
  289.                         </xsl:when>
  290.                         <xsl:when test="$cell-style-properties/@fo:vertical-align = 'Automatic'">
  291.                             <w:vAlign w:val="both"/>
  292.                         </xsl:when>
  293.                         <xsl:otherwise>
  294.                             <w:vAlign w:val="{$cell-style-properties/@fo:vertical-align}"/>
  295.                         </xsl:otherwise>
  296.                     </xsl:choose>
  297.                 </xsl:if>
  298.                 <w:tcMar>
  299.                     <xsl:if test="$cell-style-properties/@fo:padding-top">
  300.                         <w:top w:type="dxa">
  301.                             <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="$cell-style-properties/@fo:padding-top"/></xsl:call-template></xsl:attribute>
  302.                         </w:top>
  303.                     </xsl:if>
  304.                     <xsl:if test="$cell-style-properties/@fo:padding-bottom">
  305.                         <w:bottom w:type="dxa">
  306.                             <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="$cell-style-properties/@fo:padding-bottom"/></xsl:call-template></xsl:attribute>
  307.                         </w:bottom>
  308.                     </xsl:if>
  309.                     <xsl:if test="$cell-style-properties/@fo:padding-left">
  310.                         <w:left w:type="dxa">
  311.                             <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="$cell-style-properties/@fo:padding-left"/></xsl:call-template></xsl:attribute>
  312.                         </w:left>
  313.                     </xsl:if>
  314.                     <xsl:if test="$cell-style-properties/@fo:padding-right">
  315.                         <w:right w:type="dxa">
  316.                             <xsl:attribute name="w:w"><xsl:call-template name="convert2twip"><xsl:with-param name="value" select="$cell-style-properties/@fo:padding-right"/></xsl:call-template></xsl:attribute>
  317.                         </w:right>
  318.                     </xsl:if>
  319.                 </w:tcMar>
  320.                 <!-- the following code is to get the cell borders if they exsits Gary.Yang-->
  321.                 <xsl:variable name="border-top" select="$cell-style-properties/@fo:border-top | $cell-style-properties/@fo:border"/>
  322.                 <xsl:variable name="border-bottom" select="$cell-style-properties/@fo:border-bottom | $cell-style-properties/@fo:border"/>
  323.                 <xsl:variable name="border-left" select="$cell-style-properties/@fo:border-left | $cell-style-properties/@fo:border"/>
  324.                 <xsl:variable name="border-right" select="$cell-style-properties/@fo:border-right | $cell-style-properties/@fo:border"/>
  325.                 <xsl:variable name="border-line-width-top" select="$cell-style-properties/@style:border-line-width-top | $cell-style-properties/@style:border-line-width "/>
  326.                 <xsl:variable name="border-line-width-bottom" select="$cell-style-properties/@style:border-line-width-bottom | $cell-style-properties/@style:border-line-width"/>
  327.                 <xsl:variable name="border-line-width-left" select="$cell-style-properties/@style:border-line-width-left | $cell-style-properties/@style:border-line-width"/>
  328.                 <xsl:variable name="border-line-width-right" select="$cell-style-properties/@style:border-line-width-right | $cell-style-properties/@style:border-line-width"/>
  329.                 <xsl:element name="w:tcBorders">
  330.                     <xsl:if test="$border-top">
  331.                         <xsl:element name="w:top">
  332.                             <xsl:call-template name="get-border">
  333.                                 <xsl:with-param name="so-border" select="$border-top"/>
  334.                                 <xsl:with-param name="so-border-line-width" select="$border-line-width-top"/>
  335.                                 <xsl:with-param name="so-border-position" select=" 'top' "/>
  336.                             </xsl:call-template>
  337.                         </xsl:element>
  338.                     </xsl:if>
  339.                     <xsl:if test="$border-bottom">
  340.                         <xsl:element name="w:bottom">
  341.                             <xsl:call-template name="get-border">
  342.                                 <xsl:with-param name="so-border" select="$border-bottom"/>
  343.                                 <xsl:with-param name="so-border-line-width" select="$border-line-width-bottom"/>
  344.                                 <xsl:with-param name="so-border-position" select=" 'bottom' "/>
  345.                             </xsl:call-template>
  346.                         </xsl:element>
  347.                     </xsl:if>
  348.                     <xsl:if test="$border-left">
  349.                         <xsl:element name="w:left">
  350.                             <xsl:call-template name="get-border">
  351.                                 <xsl:with-param name="so-border" select="$border-left"/>
  352.                                 <xsl:with-param name="so-border-line-width" select="$border-line-width-left"/>
  353.                                 <xsl:with-param name="so-border-position" select=" 'left' "/>
  354.                             </xsl:call-template>
  355.                         </xsl:element>
  356.                     </xsl:if>
  357.                     <xsl:if test="$border-right">
  358.                         <xsl:element name="w:right">
  359.                             <xsl:call-template name="get-border">
  360.                                 <xsl:with-param name="so-border" select="$border-right"/>
  361.                                 <xsl:with-param name="so-border-line-width" select="$border-line-width-right"/>
  362.                                 <xsl:with-param name="so-border-position" select=" 'right' "/>
  363.                             </xsl:call-template>
  364.                         </xsl:element>
  365.                     </xsl:if>
  366.                 </xsl:element>
  367.             </xsl:element>
  368.             <xsl:if test="not (*) ">
  369.                 <w:p/>
  370.             </xsl:if>
  371.             <xsl:apply-templates select=" text:p | table:table | text:h | office:annotation"/>
  372.         </xsl:element>
  373.     </xsl:template>
  374.     <xsl:template name="caculate-table-cell-width">
  375.         <xsl:param name="table-cell-position"/>
  376.         <xsl:param name="table-column"/>
  377.         <xsl:choose>
  378.             <xsl:when test="$table-column/@table:number-columns-repeated">
  379.                 <xsl:choose>
  380.                     <xsl:when test="($table-cell-position - $table-column/@table:number-columns-repeated) <= 0">
  381.                         <xsl:variable name="table-cell-width" select="key('table-column-style', $table-column/@table:style-name)/style:table-column-properties/@style:column-width"/>
  382.                         <xsl:variable name="table-cell-width-in-twip">
  383.                             <xsl:call-template name="convert2twip">
  384.                                 <xsl:with-param name="value" select="$table-cell-width"/>
  385.                             </xsl:call-template>
  386.                         </xsl:variable>
  387.                         <xsl:value-of select="$table-cell-width-in-twip"/>
  388.                     </xsl:when>
  389.                     <xsl:otherwise>
  390.                         <xsl:call-template name="caculate-table-cell-width">
  391.                             <xsl:with-param name="table-cell-position" select="$table-cell-position - $table-column/@table:number-columns-repeated"/>
  392.                             <xsl:with-param name="table-column" select="$table-column/following-sibling::table:table-column[1]"/>
  393.                         </xsl:call-template>
  394.                     </xsl:otherwise>
  395.                 </xsl:choose>
  396.             </xsl:when>
  397.             <xsl:otherwise>
  398.                 <!-- if the $table-column doesn't contain the table:number-columns-repeated attribute -->
  399.                 <xsl:choose>
  400.                     <xsl:when test="($table-cell-position - 1) = 0">
  401.                         <xsl:variable name="table-cell-width" select="key('table-column-style', $table-column/@table:style-name)/style:table-column-properties/@style:column-width"/>
  402.                         <xsl:variable name="table-cell-width-in-twip">
  403.                             <xsl:call-template name="convert2twip">
  404.                                 <xsl:with-param name="value" select="$table-cell-width"/>
  405.                             </xsl:call-template>
  406.                         </xsl:variable>
  407.                         <xsl:value-of select="$table-cell-width-in-twip"/>
  408.                     </xsl:when>
  409.                     <xsl:when test="($table-cell-position - 1) > 0">
  410.                         <xsl:call-template name="caculate-table-cell-width">
  411.                             <xsl:with-param name="table-cell-position" select=" $table-cell-position - 1 "/>
  412.                             <xsl:with-param name="table-column" select="$table-column/following-sibling::table:table-column[1]"/>
  413.                         </xsl:call-template>
  414.                     </xsl:when>
  415.                     <xsl:otherwise>
  416.                         <xsl:message>
  417.                             <xsl:value-of select=" 'caculate table cell width wrong ' "/>
  418.                         </xsl:message>
  419.                     </xsl:otherwise>
  420.                 </xsl:choose>
  421.             </xsl:otherwise>
  422.         </xsl:choose>
  423.     </xsl:template>
  424. </xsl:stylesheet>
  425.